PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: Thiago Perrotta <echo dGhpYWdvcGVycm90dGE5NUBnbWFpbC5jb20K | base64 -d >

pkgname=docfetcher
_name=DocFetcher
pkgver=1.1.25
pkgrel=1
_gtkver=gtk3 # variable that controls whether GTK2 or 3(default) is to be used.
pkgdesc="A java open source desktop search application"
arch=('i686' 'x86_64')
url="http://${pkgname}.sourceforge.net/"
license=('EPL')
depends=('java-runtime>=8')
makedepends=('unzip')
optdepends=('gtk2: GTK2-based interface' 'gtk3: GTK3-based interface')
source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/docfetcher-${pkgver}-portable.zip"
  'docfetcher'
  'swt.patch'
  'docfetcher.desktop')
sha256sums=('805abba35f2078a6b882d5116dc068fdafcfc0c5922d12ca5c42b68341d6b8a8'
         'd49d1c1327b72345040c76ae510a3eaa520c82dd5c43f2a6e597f1c984b55c50'
         'edc2d63e3644eafe69229df44986c310a17eeecb06ce62818c24f55c9409ab54'
         '878ea6e2188733f13a7580606fef290ae5b547b814b33efcd61f8cef79b76b61')

prepare() {
  cd "${srcdir}"

  # Patch to add where SWT libraries will be unpacked. See the following link:
  # http://docfetcher.sourceforge.net/wiki/doku.php?id=faq  
  cd "${srcdir}/${_name}-${pkgver}/"
  patch -Np0 -i ../swt.patch
}

package() {
  cd "${srcdir}/${_name}-${pkgver}/"

  # Executable
  install -Dm755 "../${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
  
  # .desktop file
  install -Dm755 "../${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"  

  # Remove files from other platforms and other unnecessary ones
  # find . -name '*.app' -exec rm -r '{}' \;
  find . -name '*.exe' -exec rm -r '{}' \;
  find . -name '*.bat' -exec rm -r '{}' \;
  rm "Readme.txt"

  # Copy files to destination
  prefix="${pkgdir}/usr/share/${pkgname}"
  install -d "${prefix}"
  for file in *; do
    cp -a "${file}" "${prefix}/${file}"
  done
  find "${prefix}" -type d -exec chmod 0755 {} \;
  find "${prefix}" -type f -exec chmod 0644 {} \;
  
  # make start scripts executable
  chmod +x ${prefix}/DocFetcher-GTK*.sh
  
  # symlink one or other of the startup scripts for GTK2 or GTK3(default)
  if [ $_gtkver == 'gtk3' ]; then
    ln -s "/usr/share/${pkgname}/DocFetcher-GTK3.sh" "${prefix}/DocFetcher.sh"
  elif [ $_gtkver == 'gtk2' ]; then
    ln -s "/usr/share/${pkgname}/DocFetcher-GTK2.sh" "${prefix}/DocFetcher.sh"
  fi
}