PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Maintainer: Alex Grabowski <hurufu+aur@gmail.com>
pkgbase=dogelog
pkgname=(dogelog-js dogelog-py dogelog-java dogelog-license dogelog)
pkgver=1.2.5
pkgrel=9
arch=(any)
url='https://www.dogelog.ch/'
pkgdesc='The avant-garde of logic programming'
license=(custom)
options=(!strip)
source=(
    https://www.dogelog.ch/typtab/rscsrv/docs/50_archive/archive_1_2/dogelog_1_2_5.zip
    https://www.xlog.ch/izytab/rscsrv/en/docs/25_recital/17_runtime.pdf
    https://www.xlog.ch/izytab/rscsrv/en/docs/25_recital/81_conditions.pdf
)
# Checksum is from https://www.dogelog.ch/typtab/moblet/docs/50_archive/archive_1_2/dogelog_1_2_5.html
sha256sums=(
    ac929e3662f3bb539d47d12c81004b1d48b6e7cf800f93353d04905854a25a61
    ab0388caeda85ad41a4e19a096fb92cf319aaf7ead3041c27f4a4a264e9361b3
    e00f26995e012646b0dffba4c4cdc604d87458b422b4f72aae6f382dff7ec5af
)
changelog=ChangeLog

package_any() {
    install --mode=644 -Dt "$pkgdir/usr/share/$pkgbase" "$1"
}

package_dogelog-py() {
    pkgdesc='The avant-garde of logic programming (Python backend)'
    depends=(dogelog-license)
    optdepends=('python3>=3.10.14' pypy3)
    provides=(dogelog-package)
    package_any playerpy/canned/dogelog.py
}

package_dogelog-js() {
    pkgdesc='The avant-garde of logic programming (JavaScript backend)'
    depends=(dogelog-license)
    optdepends=('nodejs>=22.11.0' bun)
    provides=(dogelog-package)
    replaces=(dogelog-node)
    package_any player/canned/dogelog.mjs
}

package_dogelog-java() {
    pkgdesc='The avant-garde of logic programming (Java backend)'
    depends=('java-runtime>=21' dogelog-license)
    provides=(dogelog-package)
    package_any playerj/canned/dogelog.zip
}

package_dogelog() {
    pkgdesc='The avant-garde of logic programming (Shell wrapper)'
    depends=(dogelog-package)
    optdepends=(rlwrap)
    license=(GPL-2.0-or-later)
    install -m755 -D ../dogelog.sh "$pkgdir/usr/bin/$pkgbase"
}

package_dogelog-license() {
    pkgdesc='The avant-garde of logic programming (License agreement)'
    license=()
    install -m644 -Dt "$pkgdir/usr/share/licenses/$pkgbase" ../17_runtime.pdf ../81_conditions.pdf
}