blob: 0c0612dfe9bc7c70de9273d54a53d0ba49434d55 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Carsten Haitzler <raster@rasterman.com>
# Contributor: Doug Newgard <scimmia22 at outlook dot com>
_pkgname=ecrire
pkgname=$_pkgname-git
pkgver=r176.4e3ff1c
pkgrel=1
epoch=1
pkgdesc="Simple text editor based on EFL"
arch=('i686' 'x86_64')
url="http://www.enlightenment.org"
license=('GPL3')
depends=('efl')
makedepends=('git' 'meson')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
install=$_pkgname.install
options=('debug')
source=("git+https://git.enlightenment.org/enlightenment/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/$_pkgname"
meson --prefix /usr --buildtype release build
ninja -C build
}
package() {
cd "$srcdir/$_pkgname"
DESTDIR="${pkgdir}" ninja -C build install
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}/" "README"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" "AUTHORS" "COPYING"
}
|