blob: bd99ec9addd2d735f6e1ff96a33468f3f9937fda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Yigit Sever <yigit at yigitsever dot com>
# Contributor: Dimitris Kiziridis <ragouel at outlook dot com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
pkgname=elementary-icon-theme-git
pkgver=6.0.0.r4.g9c8e5b0f
pkgrel=1
pkgdesc='Named, vector icons for elementary OS'
arch=('any')
url='https://github.com/elementary/icons'
license=('GPL3')
groups=('pantheon-unstable')
depends=('hicolor-icon-theme')
makedepends=('git' 'meson' 'inkscape' 'xorg-xcursorgen')
provides=('elementary-icon-theme')
conflicts=('elementary-icon-theme')
options=('!emptydirs')
source=("elementary-icon-theme::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/elementary-icon-theme"
# https://wiki.archlinux.org/title/VCS_package_guidelines#Git
# Upstream has annotated tags
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/elementary-icon-theme"
if [[ -d build ]]; then
rm -rf build
fi
mkdir build
}
build() {
cd "${srcdir}/elementary-icon-theme/build"
arch-meson ../
ninja
}
package() {
cd "${srcdir}/elementary-icon-theme/build"
DESTDIR="${pkgdir}" ninja install
rm "${pkgdir}"/.VolumeIcon*
}
# vim: ts=2 sw=2 et:
|