PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Luca Weiss <aur (at) lucaweiss (dot) eu>
# Contributor: Fabio 'Lolix' Loli <lolix@disroot.org> -> https://github.com/FabioLolix
# Contributor: Antonio Rojas <arojas@archlinux.org>

pkgname=elisa-git
pkgver=24.01.90.r369.g0abb9afe
pkgrel=1
pkgdesc="Simple music player aiming to provide a nice experience for its users"
url='https://apps.kde.org/elisa/'
arch=(x86_64)
license=(LGPL-3.0-or-later)
depends=(gcc-libs
         glibc
         kcolorscheme
         kconfig
         kconfigwidgets
         kcoreaddons
         kcrash
         kdbusaddons
         kfilemetadata
         ki18n
         kiconthemes
         kio
         kirigami
         kirigami-addons
         kitemviews
         kxmlgui
         qqc2-desktop-style
         qt6-base
         qt6-declarative
         qt6-multimedia
         vlc)
makedepends=(extra-cmake-modules git kdoctools python)
provides=(elisa)
conflicts=(elisa)
source=("git+https://invent.kde.org/multimedia/elisa.git")
sha512sums=('SKIP')

pkgver() {
  cd elisa
  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cmake -B build -S elisa \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package(){
  DESTDIR="$pkgdir" cmake --install build
}