blob: 98c75db516e9fa2bd398af7e1afa58097fe2291f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Cortex
# Forked from vesktop
pkgname=equibop
_pkgname=Equibop
pkgdesc="Equibop is a Vesktop fork that gives you the performance of web Discord and the comfort of Discord Desktop, with additional plugins."
pkgver=2.0.9
# Reminder for devs: don't forget to update the electron version on equibop.sh
pkgrel=2
electron=electron33
arch=('x86_64' 'aarch64')
url="https://github.com/Equicord/Equibop"
license=('GPL3')
depends=("${electron}")
makedepends=('pnpm')
optdepends=(
'libnotify: Notifications'
'xdg-utils: Open links, files, etc'
'xdg-desktop-portal: Screensharing with Wayland'
'arrpc: Rich presence support'
)
conflicts=('equibop-bin')
source=("$url/archive/refs/tags/v${pkgver}.tar.gz"
'io.github.equicord.equibop.desktop'
'equibop.sh')
sha256sums=('0cae52c6e1c107c5e9099396e131c2b02e10868e444d6245bed02d0c21a30503'
'1e4766362fab2657e6b9a6a0a742518b545a5678f211ba25f7fdd3f5080d48d5'
'843ec77a78259b4bd0b6f065bfa07b9f4844b1bcccc5ffbb66639ebb92b60bde')
prepare() {
cd "$_pkgname-$pkgver"
# Use system's electron
# sed -i "/linux/s/^/ \"electronDist\": \"\\/usr\\/lib\\/${electron}\",\n/" package.json
}
build() {
cd "$_pkgname-$pkgver"
pnpm i
pnpm package:dir
}
package() {
cd "$srcdir"
install -d "${pkgdir}/usr/lib/${pkgname}"
install -d "${pkgdir}/usr/bin"
cp "$_pkgname-$pkgver/dist/linux-unpacked/resources/app.asar" "${pkgdir}/usr/lib/${pkgname}/"
install -Dm755 "./equibop.sh" "$pkgdir/usr/bin/equibop"
install -Dm 644 "io.github.equicord.equibop.desktop" "$pkgdir/usr/share/applications/io.github.equicord.equibop.desktop"
install -Dm 644 "$_pkgname-$pkgver/static/icon.png" "$pkgdir/usr/share/pixmaps/${pkgname}.png"
install -Dm 644 "$_pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|