blob: 8d71358c7b3d3015d72a6a8db16c80f2df6fef76 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: willemw <willemw12@gmail.com>
# Contributor: rtfreedman <rob<d0t>til<d0t>freedman< T>googlemail<d0t>com>
pkgname=exmplayer-git
pkgver=5.0.1.r39.ga1605d1
pkgrel=1
pkgdesc='Player GUI front-end. Plays any media file. Video downloader, subtitle search, audio converter/extractor, media cutter, Gif animation generator'
arch=(x86_64)
url=https://exmplayer.sourceforge.net
license=(GPL-2.0-or-later)
depends=(ffmpeg mplayer qt5-base) # kdelibs4support
optdepends=('yt-dlp: download video/audio')
makedepends=(git)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+https://github.com/rupeshs/ExMplayer.git")
sha256sums=('SKIP')
pkgver() {
git -C $pkgname describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
make -C $pkgname # KDE_SUPPORT=1
}
package() {
install -Dm644 $pkgname/debian/exmplayer.png -t "$pkgdir/usr/share/pixmaps"
install -Dm644 $pkgname/exmplayer{,_enqueue}.desktop -t "$pkgdir/usr/share/applications"
install -Dm644 $pkgname/linux_build/{fmts,sc_default.xml} -t "$pkgdir/etc/exmplayer"
install -Dm755 $pkgname/src/exmplayer -t "$pkgdir/usr/bin"
}
|