PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: loooph <loooph@gmx.de>
pkgname=fairtris-git
_basename=Fairtris
pkgver=3.0.0.4
pkgrel=1
pkgdesc="PC clone of the official classic Nintendo Tetris® game for the NES console, Linux fork"
url="https://github.com/chronoscz/Fairtris"
license=('Unlicense')
arch=(any)
depends=(sdl2 sdl2_image sdl2_mixer)
makedepends=(lazarus git)
provides=(fairtris)
conflicts=(fairtris)
source=("git+${url}")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$_basename"
    git describe --tags | sed 's/v\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

build() {
    cd "$srcdir/$_basename/source"
    lazbuild --lazarusdir=/usr/lib/lazarus --build-mode=Release Fairtris.Main.lpi
}

package() {
    cd "$srcdir/$_basename"
    install -Dt "$pkgdir/usr/bin" bin/fairtris
    install -d "$pkgdir/usr/share/fairtris"
    cp -r bin/grounds "$pkgdir/usr/share/fairtris"
    cp -r bin/sprites "$pkgdir/usr/share/fairtris"
    cp -r bin/sounds "$pkgdir/usr/share/fairtris"
    install -Dt "$pkgdir/usr/share/applications" install/snap/local/fairtris.desktop
    install -d "$pkgdir/usr/share/pixmaps/"
    install graphics/application/64.png "$pkgdir/usr/share/pixmaps/fairtris.png"
}