PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: kleintux <reg-archlinux AT klein DOT tuxli DOT ch> 
# Contributor: Philip Goto <philip.goto@gmail.com>

pkgname=feedbackd-git
pkgver=0.4.0.r0.g09396c7
pkgrel=1
pkgdesc="A daemon to provide haptic, visual, and audio feedback on events"
url="https://source.puri.sm/Librem5/feedbackd"
license=(GPL3)
arch=(i686 x86_64 armv7h aarch64)
provides=(feedbackd)
conflicts=(feedbackd)
depends=(
	dconf
	gsound
	json-glib
	libgudev
)
makedepends=(
	git
	gobject-introspection
	meson
	vala
	gi-docgen
	python-docutils
	cmake	
	libgmobile	
)
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
	cd feedbackd
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	arch-meson feedbackd build -Dgtk_doc=true -Dman=true
	meson compile -C build
}

check() {
	meson test -C build --print-errorlogs
}

package() {
	DESTDIR="${pkgdir}" meson install -C build
}