blob: 8fd8fac326718624b65d2d00d65ea7f0a72fb776 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# SELinux Maintainer: Nicolas Iooss (nicolas <dot> iooss <at> m4x <dot> org)
# SELinux Contributor: Timothée Ravier
# SELinux Contributor: Nicky726 <Nicky726@gmail.com>
#
# This PKGBUILD is maintained on https://github.com/archlinuxhardened/selinux.
# If you want to help keep it up to date, please open a Pull Request there.
pkgname=findutils-selinux
pkgver=4.10.0
pkgrel=2
pkgdesc="GNU utilities to locate files with SELinux support"
arch=('x86_64' 'aarch64')
license=('GPL-3.0-or-later')
groups=('selinux')
depends=('glibc' 'sh' 'libselinux')
makedepends=('git' 'wget' 'python')
conflicts=("${pkgname/-selinux}" "selinux-${pkgname/-selinux}")
provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}"
"selinux-${pkgname/-selinux}=${pkgver}-${pkgrel}")
url='https://www.gnu.org/software/findutils/'
source=("git+https://git.savannah.gnu.org/git/findutils.git?signed#tag=v${pkgver}")
b2sums=('a6d99d922df4c6895d9956a6902518c5f911e6ad1fdcbfc99bb083ce0a725fa4e87bb83a1a2d16e6d900755da9e9094b20f56f971c8e6a6008572cd417fe3e95')
validpgpkeys=('A5189DB69C1164D33002936646502EF796917195') # Bernhard Voelker <mail@bernhard-voelker.de>
prepare() {
cd "${pkgname/-selinux}"
./bootstrap
}
build() {
cd "${pkgname/-selinux}"
# Don't build or install locate because we use mlocate,
# which is a secure version of locate.
sed -e '/^SUBDIRS/s/locate//' -e 's/frcode locate updatedb//' -i Makefile.in
./configure --prefix=/usr
# don't build locate, but the docs want a file in there.
make -C locate dblocation.texi
make
}
check() {
cd "${pkgname/-selinux}"
make check
}
package() {
cd "${pkgname/-selinux}"
make DESTDIR="${pkgdir}" install
}
|