PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=firectl
pkgver=0.2.0
pkgrel=1
pkgdesc='A command-line tool to run Firecracker microVMs'
arch=('x86_64')
url='https://github.com/firecracker-microvm/firectl'
license=('Apache')
depends=('firecracker')
makedepends=('git' 'go')
options=('!lto')
_commit='7614c6674c633babb058f25d1e8b8c62bf888307'
source=("$pkgname::git+$url#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgname"

  git describe --tags | sed 's/^v//'
}

prepare() {
  cd "$pkgname"

  # create directory for build output
  mkdir build

  # download dependencies
  go mod download
}

build() {
  cd "$pkgname"

  # set Go flags
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"

  go build -v \
    -trimpath \
    -buildmode=pie \
    -mod=readonly \
    -ldflags "-linkmode external -extldflags ${LDFLAGS}" \
    -o build \
    .
}

package() {
  cd "$pkgname"

  install -vDm755 -t "$pkgdir/usr/bin" "build/$pkgname"
}