blob: ec67d8814803b2ddc450e924b4491b4964fd2c33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: darkelectron <darkelectron(at)mailfence.com>
# Maintainer: Eli Schwartz <eschwartz@archlinux.org>
# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
_pkgname=privacybadger
pkgname=firefox-extension-${_pkgname}
pkgver=2024.7.17
pkgrel=1
pkgdesc="Block third party tracking in your browser"
arch=('any')
url="https://www.eff.org/privacybadger"
license=('GPL3')
groups=('firefox-addons')
makedepends=("unzip")
source=("${_pkgname}-${pkgver}.xpi::https://www.eff.org/files/privacy-badger-eff-${pkgver}.xpi"
"${_pkgname}-${pkgver}.xpi.sig::https://www.eff.org/files/privacy-badger-eff-${pkgver}.xpi.sig")
noextract=("${_pkgname}-${pkgver}.xpi")
sha256sums=('047012ab01879ce1211bdc7bdf1bd96c9705f3b1162ee391ee8922640b1ad770'
'SKIP')
b2sums=('e4f9147ced67fee5ce92714785b8ec8fc78455e990fc8c551ce229e636c185137334a47f90a26a89953f43cb40b66e7d152c29d55c86b1fca3e443ac8017bc4b'
'SKIP')
validpgpkeys=('88F8662241B0C16C16E3B5A7950FC3999D80F309') # Alexei <alexei@eff.org>
prepare() {
cd "$srcdir"
unzip -qqo "${_pkgname}-${pkgver}.xpi" -d "${_pkgname}-${pkgver}"
}
package() {
depends=("firefox")
cd "${srcdir}"
if [[ -f ${_pkgname}-${pkgver}/install.rdf ]]; then
_extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' ${_pkgname}-${pkgver}/install.rdf)"
else
_extension_id="$(sed -n 's/.*"id": "\(.*\)".*/\1/p' ${_pkgname}-${pkgver}/manifest.json)"
fi
_extension_dest="${pkgdir}/usr/lib/firefox/browser/extensions/${_extension_id}"
# Should this extension be unpacked or not?
if grep -q '<em:unpack>true</em:unpack>' ${_pkgname}-${pkgver}/install.rdf 2>/dev/null; then
install -dm755 "${_extension_dest}"
cp -R ${_pkgname}-${pkgver}/* "${_extension_dest}"
chmod -R ugo+rX "${_extension_dest}"
else
install -Dm644 ${_pkgname}-${pkgver}.xpi "${_extension_dest}.xpi"
fi
}
|