PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>

pkgbase=fish-catppuccin-git
pkgname=(
	'fish-catppuccin-frappe-git'
	'fish-catppuccin-latte-git'
	'fish-catppuccin-macchiato-git'
	'fish-catppuccin-mocha-git')
_pkg="${pkgbase%-git}"
pkgver=r61.b909666
pkgrel=1
pkgdesc="Soothing pastel theme for Fish Shell"
arch=('any')
url='https://github.com/catppuccin/fish'
license=('MIT')
depends=('fish')
makedepends=('git')
install=catppuccin.install
source=("$_pkg::git+$url")
sha256sums=('SKIP')

pkgver() {
	cd "$_pkg"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

_package() {
	cd "$_pkg"
	install -Dvm644 themes/"$1.theme" -t "$pkgdir/usr/share/fish/tools/web_config/themes/"
	install -Dvm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}

package_fish-catppuccin-frappe-git() {
	pkgdesc+=' -- Frappe colorscheme'
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	_package "Catppuccin Frappe"
}

package_fish-catppuccin-latte-git() {
	pkgdesc+=' -- Latte colorscheme'
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	_package "Catppuccin Latte"
}

package_fish-catppuccin-macchiato-git() {
	pkgdesc+=' -- Macchiato colorscheme'
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	_package "Catppuccin Macchiato"
}

package_fish-catppuccin-mocha-git() {
	pkgdesc+=' -- Mocha colorscheme'
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	_package "Catppuccin Mocha"
}