blob: f59d13c14afaa6708c661e8e1fa0ff7c19e084ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: bipin kumar <kbipinkumar@pm.me>
pkgname=flair
_module=flair-brookslab
pkgver=2.0.0
pkgrel=1
pkgdesc="Tool for correction, isoform definition, and alternative splicing analysis of nanopore cDNA, native RNA, and PacBio sequencing reads"
arch=('any')
url="https://github.com/BrooksLabUCSC/flair"
license=('BSD')
depends=(
'python'
'python-numpy'
'python-tqdm'
'python-ncls'
'python-pybedtools'
'python-mappy'
'python-pysam'
'bedtools'
'samtools'
'minimap2'
)
optdepends=(
'cython'
'python-pandas'
'python-rpy2'
'r'
'r-ggplot2'
'r-qqman'
'r-deseq2'
'r-drimseq'
'r-stager'
'python-matplotlib'
'python-seaborn'
)
makedepends=(
'python-setuptools'
'cython'
'python-build'
'python-installer'
'python-wheel'
)
options=(!emptydirs)
source=("https://files.pythonhosted.org/packages/source/${_module::1}/$_module/$_module-$pkgver.tar.gz")
sha256sums=('bc1fe441e5610f19a2c95b6dc0aca588244bb7d48b3eb07b6fa424d8e251619c')
build() {
cd "$_module-$pkgver"
python -m build --wheel --no-isolation
}
package() {
cd "$_module-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|