PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: edwloef

pkgname=flow-control-git
_pkgname=flow-control
__pkgname=flow
pkgver=r901.a0d9ded
pkgrel=1
pkgdesc="a programmer's text editor"
arch=('x86_64')
url="https://github.com/neurocyte/flow"
license=('MIT')
optdepends=('ripgrep: project-wide search')
makedepends=('git' 'zig>=0.13.0' 'zig<0.14.0')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+https://github.com/neurocyte/flow.git")
sha256sums=(SKIP)

pkgver() {
    cd "${__pkgname}"

    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "${__pkgname}"

    zig build -Doptimize=ReleaseSafe
}

package() {
    cd "${__pkgname}"

    install -Dm755 "zig-out/bin/${__pkgname}" "${pkgdir}/usr/bin/${__pkgname}"
    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    install -Dm644 "contrib/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
    install -Dm644 "contrib/icons/192x192/${_pkgname}.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
}