PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>

pkgname=fossilize-git
pkgver=0.0.0+905.f67ffa9c49
pkgrel=1
pkgdesc="Library and Vulkan layer for serializing various persistent Vulkan objects which typically end up in hashmaps"
arch=(x86_64)
url="https://github.com/ValveSoftware/Fossilize"
license=(MIT)
depends=()
makedepends=(git cmake ninja)
source=("git+$url"
        git+https://github.com/KhronosGroup/SPIRV-Cross
        git+https://github.com/KhronosGroup/SPIRV-Headers
        git+https://github.com/KhronosGroup/SPIRV-Tools
        git+https://github.com/tronkko/dirent
        git+https://github.com/zeux/volk
        git+https://github.com/miloyip/rapidjson)
sha256sums=('SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP')
conflicts=(fossilize)

pkgver() {
  cd Fossilize
  printf '0.0.0+%d.%s' \
    $(git rev-list --count HEAD) \
    $(git rev-parse HEAD | head -c10)
}

prepare() {
  cd Fossilize
  git submodule init
  git config submodule."cli/SPIRV-Cross".url "$srcdir/SPIRV-Cross"
  git config submodule."cli/SPIRV-Headers".url "$srcdir/SPIRV-Headers"
  git config submodule."cli/SPIRV-Tools".url "$srcdir/SPIRV-Tools"
  git config submodule."cli/dirent".url "$srcdir/dirent"
  git config submodule."cli/volk".url "$srcdir/volk"
  git config submodule."rapidjson".url "$srcdir/rapidjson"
  git -c protocol.file.allow=always submodule update
  cmake -S . -B ../build \
    -G Ninja \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D CMAKE_BUILD_TYPE=Release
}

build() {
  ninja -C build
}

check() {
  ninja -C build test
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
}