PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Stefan Biereigel <stefan@biereigel.de>

_pkgname="fparser"
pkgname="$_pkgname-git"
pkgver=r12.a952179
pkgrel=2
pkgdesc="Function Parser for C++, Fork from http://warp.povusers.org/FunctionParser/"
url="https://github.com/thliebig/fparser"
arch=('i686' 'x86_64')
license=('LGPL-3.0-only')

makedepends=(
  'cmake'
  'git'
  'ninja'
)

provides=('fparser')
conflicts=('fparser')

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+https://github.com/thliebig/fparser.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}