PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Contributor: Bas Bleeker <bubbel@kpnplanet.nl>

pkgname=fping-git
pkgver=5.3.r1.g511aa37
pkgrel=1
pkgdesc="A utility to ping multiple hosts at once - development version"
arch=(x86_64)
url="https://www.fping.org/"
license=('BSD-4.3TAHOE')
depends=('glibc')
makedepends=('git')
provides=('fping')
conflicts=('fping')
source=("$pkgname"::'git+https://github.com/schweikert/fping.git#branch=develop')
md5sums=('SKIP')

pkgver() {
    cd "${pkgname}"
    git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./g'
}

build() {
    cd "${pkgname}"
    ./autogen.sh
    ./configure --prefix=/usr --sbindir=/usr/bin \
         --mandir=/usr/share/man \
         --enable-ipv4 \
         --enable-ipv6
    make
}

check() {
    cd "${pkgname}"
    make -k check
}

package() {
    cd "${pkgname}"
    make DESTDIR="$pkgdir/" install
    install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}