blob: 25ea5f661d0b0414bf86b7ad3748e98bcfe73fcd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Gernot Pansy <notz76 at gmail dot com>
# based on openlens-bin
_pkgname=Freelens
pkgname=freelens-bin
pkgver=0.1.4 # datasource=github-releases depName=freelensapp/freelens
pkgrel=1
pkgdesc='Free Open Source Kubernetes IDE'
arch=('x86_64' 'aarch64')
license=('MIT')
url='https://freelens.app/'
depends=('gtk3' 'libxss' 'nss')
source=("${_pkgname}.desktop")
source_x86_64=(${_pkgname}-${pkgver}-x86_64.AppImage::"https://github.com/freelensapp/freelens/releases/download/v${pkgver}/${_pkgname}-${pkgver}-linux-amd64.AppImage")
source_aarch64=(${_pkgname}-${pkgver}-aarch64.AppImage::"https://github.com/freelensapp/freelens/releases/download/v${pkgver}/${_pkgname}-${pkgver}-linux-arm64.AppImage")
sha256sums=('3864b7baedf3b707c59af6a09ebda3d95707cf681ccf48b411eb9747933ee78f')
sha256sums_x86_64=('7b8fa515f02d4c1297a44218a6f306716d5c5ff68d48ebfcbd01d80e75fbc3a6')
sha256sums_aarch64=('ebff2d8da5c14afa454483886faa34fa37a584333b2e93046bc78319dab44153')
prepare() {
chmod +x "${_pkgname}-${pkgver}-${CARCH}.AppImage"
"./${_pkgname}-${pkgver}-${CARCH}.AppImage" --appimage-extract
}
package() {
# move the entire distribution to /usr/share
mkdir -p "${pkgdir}"/usr/share/${_pkgname}
mv "${srcdir}"/squashfs-root/* \
"${pkgdir}"/usr/share/${_pkgname}
# icon
install -Dm 644 "${pkgdir}"/usr/share/${_pkgname}/usr/share/icons/hicolor/512x512/apps/freelens.png \
"${pkgdir}"/usr/share/icons/hicolor/512x512/apps/freelens.png
# desktop file
install -Dm 644 "${srcdir}"/${_pkgname}.desktop \
"${pkgdir}"/usr/share/applications/${_pkgname}.desktop
# symlink binary
mkdir -p "${pkgdir}"/usr/bin
ln -sf /usr/share/${_pkgname}/freelens \
"${pkgdir}"/usr/bin/freelens
# clean and fix permissions
find "${pkgdir}" -type d -exec chmod 755 {} \;
chmod -x "${pkgdir}"/usr/share/${_pkgname}/*.so
rm -rf "${pkgdir}"/usr/share/${_pkgname}/AppRun
rm -rf "${pkgdir}"/usr/share/${_pkgname}/lens.{desktop,png}
rm -rf "${pkgdir}"/usr/share/${_pkgname}/usr
rm -rf "${pkgdir}"/usr/share/${_pkgname}/resources/extensions/*/dist/*-arm64
}
|