PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: taotieren <admin@taotieren.com>

pkgname=fungw-svn
pkgver=r825
pkgrel=1
pkgdesc="tiny, portable library written in C (C89) that manages dynamic function calls across different programming languages"
arch=($CARCH)
url="http://www.repo.hu/projects/fungw"
license=('LGPL-2.0-or-later')
provides=(${pkgname%-svn})
conflicts=(${pkgname%-svn})
depends=(
    glibc
    #     genht
)
makedepends=(
    subversion
)
optdepends=(
    lua
    perl
    tcl
    python
    duktape
    mujs
    'python2'
    'libmawk>=1.0.3'
)
source=("svn://svn.repo.hu/fungw/trunk")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/trunk/"
    local ver="$(svnversion)"
    printf "r%s" "${ver//[[:alpha:]]/}"
}

build() {
    cd "$srcdir/trunk/"
    ./configure --prefix=/usr
    make LDFLAGS="-Wl,-z,now -Wl,-z,relro"
}

package() {
    cd "$srcdir/trunk/"
    make DESTDIR="$pkgdir/" install
}