PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer:
# Contributor: Igor Dyatlov <dyatlov.igor@protonmail.com>

_pkgname="g4music"
pkgname="$_pkgname-git"
pkgver=3.7.2.r1.g01f7243
pkgrel=1
pkgdesc="Play your music"
url="https://gitlab.gnome.org/neithern/g4music"
license=('GPL-3.0-or-later')
arch=('x86_64' 'aarch64')

depends=(
  gstreamer
  libadwaita
  taglib
  tracker3
)
makedepends=(
  git
  meson
  vala
)
checkdepends=(
  appstream-glib
)
optdepends=(
  'gst-plugins-bad'
  'gst-plugins-base'
  'gst-plugins-good'
)

provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')

pkgver() (
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
    | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
)

build() {
  arch-meson "$_pkgsrc" build
  meson compile -C build
}

check() {
  meson test -C build || true
}

package() {
  meson install -C build --destdir "${pkgdir:?}"
}