PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29

pkgname=gauche-full
pkgver=0.9.15
pkgrel=1
pkgdesc="R7RS Scheme implementation developed to be a handy script interpreter"
arch=('x86_64')
url='https://practical-scheme.net/gauche/'
depends=('libatomic_ops' 'libxcrypt' 'slib')
makedepends=('gauche')
license=('BSD')
provides=('gauche')
conflicts=('gauche' 'gauche-git')
source=("https://github.com/shirok/Gauche/releases/download/release${pkgver//./_}/Gauche-${pkgver}.tgz")
b2sums=('1b4cbc764ea3af78bc736ce9a8ff083318366fbf3197ebc5060222b8df93ed426ca4b3b90402cd604e110bcfa8fb46c0d4c5f35be39899cc89dc82a671372bf9')

build() {
  cd Gauche-$pkgver
  BUILD_GOSH=/usr/bin/gosh
  CFLAGS+=' -ffat-lto-objects -w'
  ./configure --prefix=/usr --enable-multibyte=utf-8 --enable-threads=pthreads \
    --with-slib=/usr/share/slib --with-tls=mbedtls-internal
  make
}

package() {
  cd Gauche-$pkgver
  make DESTDIR="$pkgdir" install-pkg install-doc
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  touch -d "$_info_page_date" "$pkgdir"/usr/share/info/gauche-ref*info*.gz
}