PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=gettext-git
pkgver=0.21.r12.ge645b7d56
pkgrel=1
pkgdesc="GNU internationalization library"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/gettext/"
license=('GPL3')
depends=('glibc' 'glib2' 'gperf' 'libunistring' 'ncurses')
makedepends=('git' 'fpc' 'grep' 'help2man' 'wget' 'xz')
provides=("gettext=$pkgver")
conflicts=('gettext')
source=("git+https://git.savannah.gnu.org/git/gettext.git")
sha256sums=('SKIP')


prepare() {
  cd "gettext"

  git submodule update --init --recursive
}

pkgver() {
  cd "gettext"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "gettext"

  ./autogen.sh
  ./configure \
    --prefix="/usr" \
    --without-gettext-tools
  make maintainer-update-po-local
}

check() {
  cd "gettext"

  make check
}

package() {
  cd "gettext"

  make DESTDIR="$pkgdir" install
}