blob: 725873bcb2e540069b3bc451811f1dc0778f48d4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Gesh <gesh@gesh.uni.cx>
pkgname=ghcid-static-git
_pkgname="${pkgname%-static-git}"
pkgver=0.8.9.r1.gb7dc5c4
pkgrel=4
pkgdesc='GHCi based bare bones IDE'
arch=('i686' 'x86_64')
url="https://github.com/ndmitchell/${_pkgname}"
license=('BSD-3-Clause')
provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")
depends=('gmp')
makedepends=('git' 'cabal-install')
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags --long \
| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$pkgname"
cabal update
cabal configure --prefix=/usr --docdir=/usr/share/doc/"$pkgname" \
--enable-tests
cabal build --only-dependencies
}
build() {
cd "$pkgname"
cabal build --offline
}
check() {
cd "$pkgname"
cabal test
}
package() {
cd "$pkgname"
mkdir -p "$pkgdir/usr/bin"
cabal install --install-method=copy --installdir "$pkgdir/usr/bin"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et
|