blob: fe792fdb4f7a67ca4e675a206c851165a4dcc3f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Pol Rivero < aur AT polrivero DOT com >
# Contributor: Padraic Fanning < fanninpm AT miamioh DOT edu >
# Contributor: Jake <aur@ja-ke.tech>
# Contributor: Ian MacKay <immackay0@gmail.com>
_pkgname='github-desktop-plus'
pkgname="${_pkgname}-bin"
pkgver=0.3.2
pkgrel=1
pkgdesc="Work-in-progress fork of GitHub Desktop with extra features and improvements."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/pol-rivero/github-desktop-plus"
license=('MIT')
depends=(
'curl'
'git'
'libsecret'
'libxss'
'nspr'
'nss'
'org.freedesktop.secrets'
'unzip'
)
optdepends=('hub: CLI interface for GitHub.')
provides=(${_pkgname})
conflicts=(${_pkgname})
source=(${_pkgname}.desktop)
_common_download_url="${url}/releases/download/v${pkgver}/GitHubDesktopPlus-v${pkgver}-linux"
source_x86_64=(${_common_download_url}-x86_64.deb)
source_aarch64=(${_common_download_url}-arm64.deb)
source_armv7h=(${_common_download_url}-armhf.deb)
sha256sums=('ef93d32f46b31818ffea85959f5ac67353df2c4da351b273108765b80c7f080d')
sha256sums_x86_64=('5ed532caaa8e01db563b6f94c2944a73cfeabd71a988d15bac3ee0fd1db1ab8c')
sha256sums_aarch64=('51703e26837940d74f9dde5fc2dcb590998197942a7683f7238b959764663285')
sha256sums_armv7h=('dedb441944cba26e1b7e41e02263af9eb4ccd59b4ac92c731dc3b9e0c86178f5')
package() {
tar xf data.tar.xz -C "${pkgdir}"
install -d "${pkgdir}/opt/${_pkgname}"
mv "${pkgdir}/usr/lib/github-desktop/"* "${pkgdir}/opt/${_pkgname}/"
rmdir "${pkgdir}/usr/lib/github-desktop"
rmdir "${pkgdir}/usr/lib"
mv "${pkgdir}/usr/share/doc/github-desktop" "${pkgdir}/usr/share/doc/${_pkgname}"
mv "${pkgdir}/usr/share/lintian/overrides/github-desktop" "${pkgdir}/usr/share/lintian/overrides/${_pkgname}"
find "${pkgdir}/usr/share/icons" -name 'github-desktop.png' -execdir mv {} "${_pkgname}.png" \;
rm "${pkgdir}/usr/share/applications/github-desktop.desktop"
install -Dm644 "${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
ln -sf "/opt/$_pkgname/github-desktop" "${pkgdir}/usr/bin/$_pkgname"
rm "${pkgdir}/usr/bin/github-desktop"
}
|