blob: 70448cf52927518fcce8019fe0cb0216ae03bfdf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Michał Wojdyła < micwoj9292 at gmail dot com >
# Maintainer: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>
# Contributor: Ricardo Vieira <ricardo.vieira@tecnico.ulisboa.pt>
# Contributor: Axper Jan <483ken _at_ gmail _dot_ com
# Contributor: Daniel Kirchner <ekpyron at lavabit dot com>
_pkgbase=glfw
pkgname=glfw-git
pkgver=3.4.r17.gb35641f4
pkgrel=2
pkgdesc="Free, open source, portable framework for OpenGL application development (git version)"
arch=('x86_64' 'armv7h' 'aarch64')
url="http://www.glfw.org/"
license=('Zlib')
depends=('libgl' 'libxkbcommon')
makedepends=('mesa' 'cmake' 'doxygen' 'vulkan-headers' 'vulkan-icd-loader'
'extra-cmake-modules' 'wayland-protocols' 'libxi' 'libxrandr'
'libxcursor' 'libxinerama' 'git' 'ninja')
conflicts=('glfw' 'glfw-x11' 'glfw-wayland')
provides=('glfw' 'glfw-x11' 'glfw-wayland')
replaces=('glfw-x11-git' 'glfw-wayland-git')
optdepends=('libgl: for OpenGL support'
'opengl-driver: for OpenGL support'
'vulkan-icd-loader: for Vulkan support'
'vulkan-driver: for Vulkan support')
source=("$_pkgbase::git+https://github.com/glfw/glfw")
sha256sums=('SKIP')
pkgver() {
cd $_pkgbase
git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}
build() {
mkdir -p $_pkgbase/build
cd $_pkgbase/build
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_SHARED_LIBS=ON \
-DGLFW_BUILD_EXAMPLES=OFF \
-DGLFW_BUILD_TESTS=OFF \
-DGLFW_BUILD_WAYLAND=ON \
-Wno-dev \
-G Ninja \
..
ninja
}
package() {
cd $_pkgbase/build
DESTDIR="$pkgdir" ninja install
install -Dm644 ../LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
# vim:set ts=2 sw=2 et:
|