PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

# Maintainer:  Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>

pkgname="glyph"
pkgver=1.0.10
pkgrel=1
pkgdesc="Convert images/video to ASCII art"
arch=('x86_64')
url="https://github.com/seatedro/${pkgname}"
license=('MIT')
depends=('ffmpeg' 'glibc') # 'ffmpeg6.1'
makedepends=('zig')
replaces=('asciigen')
_zig_deps=("zig-clap-0.9.1.tar.gz::https://github.com/Hejsil/zig-clap/archive/refs/tags/0.9.1.tar.gz"
           "stb-f75e8d1cad7d90d72ef7a4661f1b994ef78b4e31.tar.gz::https://github.com/nothings/stb/archive/f75e8d1cad7d90d72ef7a4661f1b994ef78b4e31.tar.gz")
_pkgsrc="${pkgname}-${pkgver}"
noextract=("${_zig_deps[@]%%::*}")
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
        "${_zig_deps[@]}")
sha256sums=('1cfb17da971cc0daac9d0a7744dd1c05fd3382b2522d64e62cdfb28a8faf5d84'
            'eeac66ff8c5bfb9f0c186fa2533b2c52d47dece1b67518c0ab24b40407ade076'
            'bc6ccf08bec08fea8ef423c7117dca06d2f62d2b27c5485f6865584b533fa7fa')

prepare() {
  cd "${srcdir}"
  for dep in "${_zig_deps[@]}"; do
    zig fetch --global-cache-dir ./zig-global-cache "${dep%%::*}"
  done
}

build() {
  # export PKG_CONFIG_PATH="/usr/lib/ffmpeg6.1/pkgconfig:$PKG_CONFIG_PATH"

  # -Doptimize=ReleaseSafe compiles fine but errors out on runtime:
  # Illegal instruction at address 0x11e45d3
  # ???:?:?: 0x11e45d3 in ??? ()
  # Unwind information for `:0x11e45d3` was not available, trace may be incomplete
  # 
  # Aborted (core dumped)

  cd "${srcdir}/${_pkgsrc}"
  DESTDIR="build" zig build \
    --summary all \
    --prefix /usr \
    --search-prefix /usr \
    --global-cache-dir "${srcdir}/zig-global-cache" \
    --system "${srcdir}/zig-global-cache/p" \
    --verbose \
    -Dtarget=native-linux.6.1-gnu.2.39 \
    -Dcpu=baseline \
    -Doptimize=ReleaseFast
}

# check() {
#   cd "${srcdir}/${_pkgsrc}"
#   DESTDIR="build" zig build test \
#     --summary all \
#     --prefix /usr \
#     --search-prefix /usr \
#     --global-cache-dir "${srcdir}/zig-global-cache" \
#     --system "${srcdir}/zig-global-cache/p" \
#     --verbose \
#     -Dtarget=native-linux.6.1-gnu.2.39 \
#     -Dcpu=baseline \
#     -Doptimize=ReleaseFast
# }

package() {
  cd "${srcdir}/${_pkgsrc}"
  cp -va build/* "${pkgdir}"

  install -vDm644 "readme.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
  install -vDm644 "LICENSE"   "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}