PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: shtrophic <aur at shtrophic dot net>

pkgname=gmlghd
pkgver=1.1
pkgrel=1
pkgdesc='The gemlog http daemon'
arch=('x86_64' 'aarch64')
url='https://git.sr.ht/~shtrophic/gmlghd'
license=('AGPL-3.0-or-later')
makedepends=('git' 'meson')
depends=(
    'confuse'
    'libbsd'
    'libevent'
    'libretls'
)
optdepends=(
    'nginx: fastcgi reverse proxy'
)

backup=('etc/gmlghd.conf')
source=(
	"$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
	"$pkgname-$pkgver.tar.gz.asc::$url/archive/$pkgver.tar.gz.asc"
	"sysusers-$pkgname.conf"
	"tmpfiles-$pkgname.conf"
	"mime.types"
	"$pkgname.example.conf"
	"$pkgname.service"
)
validpgpkeys=(10F1CC925057D456798EBF9C1B3EB6FE2D338B4A)
sha256sums=('7a5dbfa6f33e23ba1cfb962edda4610f8e8f92a55cb98f77d1fc315966074a2c'
            'SKIP'
            'a73c3d9a9798c307b70be4e764cb7023dd7a0ab4a21c906e72663a7cb45ebaf2'
            '99fe77ece238d533bba8e849c4b830d534e8ccc193cf9e291af257f60180823d'
            '27040f1df57b570b3117bd30ceb5685fbfa5aba61108f37cf86f0304d4f29f09'
            'c3d26f48b57bf51b33ef9f1dded4270b439cfa5a6642186071a64affc44c1494'
            '7a26e5d17796e4adec3f6dc4c22f03b68aab08be403c9d316b3fbac1264cad9f')

prepare() {
	cd "$srcdir/$pkgname-$pkgver"
	meson subprojects download
}

build() {
	cd "$srcdir/$pkgname-$pkgver"

	meson setup builddir --buildtype release --prefix=/usr --wrap-mode=nodownload
	meson compile -C builddir
}

package() {
	cd "$srcdir/$pkgname-$pkgver"

	meson install -C builddir --destdir "$pkgdir" --skip-subprojects foocgi

	install -Dm 644 "$srcdir/sysusers-$pkgname.conf" "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
	install -Dm 644 "$srcdir/tmpfiles-$pkgname.conf" "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
	install -Dm 644 "$srcdir/$pkgname.service" -t "$pkgdir/usr/lib/systemd/system"

	install -Dm 640 "$srcdir/$pkgname.example.conf" "$pkgdir/etc/$pkgname.conf"
	install -Dm 644 "$srcdir/mime.types" -t "$pkgdir/usr/share/$pkgname"

	install -Dm 644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
	install -Dm 644 gmlghd.example.conf -t "$pkgdir/usr/share/doc/$pkgname"
}