PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Tim Yang <protonmail = timdyang>
pkgname=gnome-shell-extension-x11gestures
_uuid=x11gestures@joseexposito.github.io
pkgver=24
pkgrel=1
pkgdesc="Enable GNOME Shell multi-touch gestures on X11"
arch=('any')
url="https://github.com/JoseExposito/gnome-shell-extension-x11gestures"
license=('GPL-2.0-or-later')
depends=('gnome-shell' 'touchegg')
makedepends=('git')
source=("git+https://github.com/JoseExposito/gnome-shell-extension-x11gestures.git#tag=$pkgver")
sha256sums=('e7c85eef996cdacf84f97679f24ca9c0fe68e75cd05b75b6013b1f4d4e4b1e15')

build() {
  cd "$pkgname"
  gnome-extensions pack \
    --extra-source=src/ \
    --force
}

package() {
  cd "$pkgname"
  install -d "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}"
  bsdtar -xvf "${_uuid}.shell-extension.zip" -C \
    "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/" --no-same-owner

  install -Dm644 schemas/org.gnome.shell.extensions.x11gestures.gschema.xml -t \
    "$pkgdir/usr/share/glib-2.0/schemas/"
  rm -r "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/schemas/"
}