blob: daab4fb8995d1342b020b9a98875595ae0f6e2a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Adrià Arrufat (swiftscythe) <swiftscythe@gmail.com>
# Contributor: Pellegrino Prevete (tallero) <pellegrinoprevete@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
_pkgname=gnome-terminal
pkgname="${_pkgname}-git"
pkgver=3.97.0+r27+g63cc638d
pkgrel=1
pkgdesc="The GNOME Terminal Emulator"
url="https://wiki.gnome.org/Apps/Terminal"
arch=(x86_64)
license=(GPL)
depends=(
dconf
glib2
gsettings-desktop-schemas
gtk4
hicolor-icon-theme
libadwaita
libx11
pango
vte4
)
makedepends=(
docbook-xsl
git
gnome-shell
libnautilus-extension
meson
python-packaging
yelp-tools
)
optdepends=(
"libnautilus-extension: Nautilus integration"
)
provides=("gnome-terminal")
conflicts=("gnome-terminal")
groups=(gnome-extra gnome-extra-git)
source=("git+https://gitlab.gnome.org/GNOME/${_pkgname}.git")
b2sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd "${_pkgname}"
}
build() {
local meson_options=(
-D b_lto=false
)
arch-meson "${_pkgname}" build "${meson_options[@]}"
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "${pkgdir}"
}
# vim:set sw=2 sts=-1 et:
|