blob: e2ba3cb67fdd171ac203f035a4dc2b00bf81135f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Michał Wojdyła < micwoj9292 at gmail dot com >
# Contributor: Rafael Fontenelle <rafaelff@gnome.org>
pkgname=gnun
pkgver=1.5
pkgrel=1
pkgdesc="GNUnited Nations, build system for www.gnu.org translations"
arch=(any)
url="https://www.gnu.org/software/gnun/"
license=('GPL-3.0-or-later')
depends=('cvs' 'subversion' 'bzr' 'po4a' 'libxml2' 'mailutils' 'sed' 'wdiff' 'gawk')
backup=(etc/gnun/gnun.conf)
source=("http://ftp.gnu.org/gnu/gnun/$pkgname-$pkgver.tar.gz"{,.sig})
sha256sums=('c618234f75c3d63e6a2db4d61039bbb95bed78f32889e6d1070c1bd6b62519a3'
'SKIP')
validpgpkeys=('BD9D4DEE7B2FF1CBEF2EE0C4E0ACD3E0CBE7874A')
# Ineiev (fencepost) <ineiev@gnu.org>
prepare() {
cd "$pkgname-$pkgver"
# gnu-mail from mailutils
sed -i 's/\[mail\]/[gnu-mail]/' configure.ac
autoreconf
}
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr \
--libexecdir=/usr/share/gnun/scripts \
--sysconfdir=/etc/gnun \
--enable-multiviews
make
}
check() {
cd "$pkgname-$pkgver"
make -k check
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
}
|