blob: a6d0658cc1d945324d2aa8e6df5f541eeed30f3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Nimrod Maclomhair <nimrod4garoa@gmail.com>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
_pkgname=gnuplot
pkgname=gnuplot-headless
pkgver=6.0.2
pkgrel=2
pkgdesc='Plotting package which outputs to PostScript, PNG, GIF, and others, without X deps'
arch=('i686' 'x86_64' 'aarch64' 'aarch32')
url='http://www.gnuplot.info'
license=(LicenseRef-Gnuplot)
depends=(gcc-libs
glibc
libcerf
lua
readline)
makedepends=(texlive-latexextra)
provides=(gnuplot)
conflicts=(gnuplot)
source=(https://downloads.sourceforge.net/sourceforge/$_pkgname/$_pkgname-$pkgver.tar.gz
lua53_compat.patch)
sha256sums=('f68a3b0bbb7bbbb437649674106d94522c00bf2f285cce0c19c3180b1ee7e738'
'bfd8a61abbf4491c74225cb9fd252619d4fc29751838bcb4c0639ffe05a00695')
prepare() {
cd $_pkgname-$pkgver
patch -p1 < "$srcdir"/lua53_compat.patch
}
build() {
cd $_pkgname-$pkgver
# If you want png and jpeg terminal support, set --with-gd and get
# add "gd-headless" as an depency.
MAKEINFO=/usr/bin/makeinfo \
./configure --prefix=/usr \
--libexecdir=/usr/bin \
--with-gihdir=/usr/share/gnuplot \
--with-readline=gnu \
--with-bitmap-terminals \
--with-texdir=/usr/share/texmf/tex/latex/gnuplot \
--disable-x11-mbfonts \
--disable-x11-external \
--disable-wxwidgets \
--without-cairo \
--with-qt=no \
--disable-raise-console \
--with-x=no \
--with-aquaterm=no \
--with-gd=no
make pkglibexecdir=/usr/bin
}
package() {
cd $_pkgname-$pkgver
make pkglibexecdir=/usr/bin DESTDIR="$pkgdir" install
install -Dm644 Copyright -t "$pkgdir"/usr/share/licenses/$pkgname
rm -f "$pkgdir"/usr/share/texmf-dist/ls-R
}
|