PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: George Rawlinson <george@rawlinson.net.nz>

_pkgname=goat
pkgname=${_pkgname}-git
pkgver=r151.7f25d1a
pkgrel=1
pkgdesc="Database management frontend written in Qt5 (git version)"
arch=('i686' 'x86_64')
#arch=('any')
url="https://github.com/mispp/goat"
license=('GPL')
provides=(goat)
depends=(hicolor-icon-theme qt5-base)
makedepends=(git qt5-tools)
source=("git+https://github.com/mispp/goat.git")
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build

  # create Makefile with QMake
  qmake-qt5 \
    "${srcdir}/${_pkgname}/${_pkgname}.pro" \
    PREFIX="/usr"

  # build package
  make
}

package() {
  # make install has some issues, so package manually
  #make -C build INSTALL_ROOT="${pkgdir}" install

  # add binary
  install -Dm755 -t "${pkgdir}/usr/bin" "${srcdir}/build/goat"

  # add .desktop
  install -Dm644 -t "${pkgdir}/usr/share/applications" "${srcdir}/${_pkgname}/packaging/${_pkgname}.desktop"

  # add icon
  install -Dm644 -t "${pkgdir}/usr/share/icons/hicolor/16x16/apps" "${srcdir}/${_pkgname}/packaging/${_pkgname}.png"
}