blob: 0dd504487e1d46a04670eac6590cd08369a54e58 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: FzerorubigD <Fzerorubigd {AT} GMail {DOT} com>
pkgname=gpaste-git
pkgver=3.22.1+23+g0923e96
pkgrel=1
pkgdesc="Clipboard management system"
url="http://www.imagination-land.org/tags/GPaste.html"
license=(GPL3)
arch=(i686 x86_64)
depends=(gtk3)
makedepends=(intltool vala appstream-glib gobject-introspection gnome-shell gnome-control-center git)
optdepends=("wgetpaste: Upload clipboard contents")
provides=("gpaste=$pkgver")
conflicts=(gpaste)
options=(!emptydirs)
source=("$pkgname::git+https://github.com/keruspe/gpaste.git#branch=master")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^v//;s/-/+/g'
}
prepare() {
arch-meson "$pkgname" "$pkgname/build"
}
build() {
meson compile -C "$pkgname/build"
}
check () {
meson test -C "$pkgname/build"
}
package() {
meson install --destdir "$pkgdir" -C "$pkgname/build"
}
|