PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Rod Kay <rodakay5 at gmail dot com>

pkgname=gpr-unit-provider
pkgdesc='A unit provider for Libadalang based on GPR project analysis library.'
pkgver=23.0.0
pkgrel=2

url=https://github.com/AdaCore/gpr-unit-provider
arch=(i686 x86_64)
license=(GPL3 custom)

depends=(gpr libadalang)
makedepends=(gprbuild)

source=($pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz)
sha256sums=(08c8194812042134730b4bb4cb5ac8761cb7798f57dfbee2dbf41913b5f8b382)


build()
{
    cd $srcdir/$pkgname-$pkgver

    make ENABLE_SHARED=no                \
         GPR_UNIT_PROVIDER_BUILD=release \
         PROCESSORS=0
}


package()
{
    cd $srcdir/$pkgname-$pkgver

    make ENABLE_SHARED=no                \
         GPR_UNIT_PROVIDER_BUILD=release \
         PROCESSORS=0                    \
         prefix="$pkgdir/usr"            \
         install

    # Install the license.
    #
    install -D -m644     \
       COPYING3        \
       $pkgdir/usr/share/licenses/$pkgname/COPYING3

    # Install the custom license.
    #
    install -D -m644     \
       COPYING.RUNTIME \
       $pkgdir/usr/share/licenses/$pkgname/COPYING.RUNTIME
}