blob: 2762c5899405c38ea533ccdf89bdb2927417c342 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_name=("protoc-gen-grpc-gateway" "protoc-gen-openapiv2")
pkgname="grpc-gateway"
pkgver=2.26.3
pkgrel=1
pkgdesc="gRPC to JSON proxy generator following the gRPC HTTP spec"
arch=('aarch64' 'x86_64')
url="https://grpc-ecosystem.github.io/grpc-gateway/"
_url="https://github.com/grpc-ecosystem/${pkgname}"
license=('BSD-3-Clause')
depends=('glibc' 'protobuf' 'protoc-gen-go' 'protoc-gen-go-grpc')
makedepends=('go')
provides=("${_name[@]}")
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${_url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('264f12df71a1419576869a994a728e07f0a3ba8b991aff21b40433026229651f')
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
for _binary in "${_name[@]}"; do
go build -o ./"build/${_binary}" ./"${_binary}"
done
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
for _binary in "${_name[@]}"; do
install -vDm755 "build/${_binary}" "${pkgdir}/usr/bin/${_binary}"
done
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|