blob: b28e270b9aaf822dd8aa3ffc5d8f5107adab3fd1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Contributor: Lex Black <autumn-wind@web.de>
## GPG key: https://greenbone.net/GBCommunitySigningKey.asc
pkgname=gsad
pkgver=24.2.3
pkgrel=1
pkgdesc='server talking to the Greenbone Vulnerability Management daemon (gvmd)'
arch=('x86_64')
url="https://github.com/greenbone/gsad"
license=('AGPL-3.0-only')
groups=('greenbone-vulnerability-manager')
depends=(
'gvmd'
'gvm-libs'
'gnutls'
'libgcrypt'
'libmicrohttpd'
'libglib-2.0.so'
'libxml2.so'
'zlib'
)
makedepends=('cmake' 'xmltoman')
optdepends=('logrotate: for rotating logs')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz"
"$pkgname-$pkgver.tar.gz.asc::$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz.asc"
"gsad.tmpfiles")
sha256sums=('8c9a08bfc1a7986f61b31482d5ac690dbd8b20cdc293a087bc32163c190cdc82'
'SKIP'
'9d978e755f969c8635f1f729b38c2c116e20a954925322c33df1859cb3031f60')
validpgpkeys=('8AE4BE429B60A59B311C2E739823FAA60ED1E580') # GVM Transfer Integrity
prepare() {
cd "$pkgname-$pkgver"
sed -i '/-Werror/d' CMakeLists.txt
}
build() {
cmake \
-B build \
-S "$pkgname-$pkgver" \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSBINDIR=/usr/bin \
-DLIBDIR=/usr/lib \
-DSYSCONFDIR=/etc \
-DLOCALSTATEDIR=/var \
-DGVMD_RUN_DIR=/run/gvmd \
-DGSAD_RUN_DIR=/run/gsad
make -C build
}
package() {
make DESTDIR="${pkgdir}/" -C build install
install -Dm 644 ${pkgname}.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/${pkgname}.conf
}
|