blob: 93adc125b44bb2cc6638ab7cbdb885d966d4f853 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Nebulosa <nebulosa2007-at-yandex-dot-ru>
pkgname=gsconnect
pkgver=62
pkgrel=1
pkgdesc="KDE Connect implementation. CLI usage without Gnome environment"
arch=(x86_64)
url="https://github.com/GSConnect/gnome-shell-extension-$pkgname"
license=('CC-BY-4.0 OR CC-BY-SA-3.0 OR CC0-1.0 OR GPL-2.0-or-later OR MPL-2.0')
depends=(
dbus
dconf
gjs
glib2
glibc
gobject-introspection
hicolor-icon-theme
libpulse
python
)
makedepends=(
appstream
desktop-file-utils
eslint
flake8
git
glib2-devel
gtk-update-icon-cache
meson
python-black
)
optdepends=(
'evolution-data-server: contacts integration'
'gsound: sound effects'
'nemo-python: Nemo integration'
'python-nautilus: Nautilus integration'
'python-pydbus: for fetch gsconnect status for Waybar'
'waybar: highly customizable wayland bar'
'wl-clipboard: command-line copy/paste utilities for wayland'
'wtype: xdotool type for wayland'
'ydotool: generic command-line automation tool'
)
conflicts=(gnome-shell-extension-$pkgname)
options=(!debug)
source=(
$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz
$pkgname.service
gvc::git+https://github.com/JingMatrix/gvc.git
)
b2sums=('e33fddd6b8cabb702fdae466be3e3e970c45a57faacf3bdccbc56a8d0a7f077cf0aafd977a9e8868c961c6b2228e38ae9ddc96cfe8315f39b62d90245e20f2ee'
'ecd31b50393dbbf23b5f33d16d11573200ce28fd818b99e3f54f269287c505b724fc55f0135809c679629842448b29f7986bed309baa6193aaf1211f144171b4'
'SKIP')
build() {
local meson_options=(
-D installed_tests=false
-D firewalld=true
-D nemo=true
)
arch-meson gvc gvc-build
meson configure gvc-build --no-pager
meson compile -C gvc-build
arch-meson gnome-shell-extension-$pkgname-$pkgver gsconnect-build "${meson_options[@]}"
meson configure gsconnect-build --no-pager
meson compile -C gsconnect-build
}
package() {
meson install -C gvc-build --destdir "$pkgdir"
meson install -C gsconnect-build --destdir "$pkgdir"
install -vDm644 $pkgname.service -t "$pkgdir"/usr/lib/systemd/user/
}
|