PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>

pkgname=gtuber
pkgver=r452.468bf02
pkgrel=1
_commit=468bf02a8adcf69b1bd6dd7b5dbcdcc0bfdb6922
pkgdesc="C library to fetch media info from websites (bilibili, lbry, niconico, reddit, twitch, youtube)"
arch=(x86_64)
url="https://github.com/Rafostar/gtuber"
license=('LGPL-2.1-only')
depends=(
  glib2
  glibc
  gstreamer
  json-glib
  libsoup3
  libxml2
)
makedepends=(
  git
  glib2-devel
  gobject-introspection
  meson
  vala
)
provides=(gst-plugins-gtuber=$pkgver)
source=("git+https://github.com/Rafostar/gtuber.git#commit=$_commit")
b2sums=('b8d0dc56c9797a3323460eb947814c3b4f8bd459729bb4cc2c293e071d322fc9955923dc81f36513dc3d1e3327f1ee0c131a2e02a36d8d07768454d007032ccf')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  local meson_options=(
    # Gtuber
    -D introspection=enabled
    -D vapi=enabled
    -D doc=true
    -D tests=false # broken

    # Bin
    -D gtuber-dl=enabled

    # GStreamer
    -D gst-gtuber=enabled

    # Utils
    -D utils-common=enabled
    -D utils-json=enabled
    -D utils-xml=enabled
    -D utils-youtube=enabled

    # Plugins
    -D bilibili=enabled
    -D crunchyroll=disabled # broken
    -D invidious=disabled # broken
    -D lbry=enabled
    -D niconico=enabled
    -D peertube=disabled # broken
    -D piped=disabled # broken
    -D reddit=enabled
    -D twitch=enabled
    -D youtube=enabled
  )

  arch-meson gtuber build "${meson_options[@]}"
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir" --no-rebuild	
}