PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Luigi311 <aur@luigi311.com>
pkgname=harbour-shutter-git
pkgver=r73.a9cb88b
pkgrel=1
pkgdesc='A camera application designed for Sailfish which exposes all available camera parameters to the user.'
arch=('x86_64' 'aarch64')
url="https://github.com/piggz/harbour-shutter"
branch="main"
license=('GPLv2+')
depends=('qt5-multimedia' 'qt5-quickcontrols' 'qt5-sensors' 'libexif' 'libcamera' 'qt5-quickcontrols2' 'kirigami2' 'opencv')
makedepends=('git' 'qt5-base' 'vtk' 'hdf5' 'glew' 'abseil-cpp' 'fmt')
checkdepends=()
optdepends=()
provides=('harbour-shutter')
conflicts=('harbour-shutter')
replaces=('harbour-shutter')
source=("${pkgname}::git+${url}.git#branch=${branch}")
md5sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "${srcdir}/${pkgname}"
	qmake-qt5 \
		PREFIX=/usr \
		QMAKE_CFLAGS="${CFLAGS}" \
		QMAKE_CXXFLAGS="${CXXFLAGS}" \
		QMAKE_LFLAGS="${LDFLAGS}" \
		FLAVOR="kirigami"

	make
}

package() {
	cd "${srcdir}/${pkgname}"
	make INSTALL_ROOT="$pkgdir" install
}