blob: 61df4a74caa9b3238b2edba98dfb699ff75aaf5c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: dringsim <dringsim@qq.com>
_hkgname=ghc-syntax-highlighter
pkgname=haskell-ghc-syntax-highlighter
pkgver=0.0.8.0
pkgrel=1
pkgdesc="Syntax highlighter for Haskell using the lexer of GHC"
license=(BSD-3-Clause)
arch=('x86_64')
url="https://hackage.haskell.org/package/$_hkgname"
depends=(ghc-libs haskell-ghc-lib-parser)
makedepends=(ghc)
source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
sha256sums=('47649e6d25e506c0b929b83b426b8392c3383657536b4cca8e0e97a341c2cbe8')
build() {
cd "$_hkgname-$pkgver"
runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
--prefix=/usr --docdir="/usr/share/doc/$pkgname" --datasubdir=$pkgname --enable-tests \
--dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
--ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
--ghc-option='-pie'
runhaskell Setup build $MAKEFLAGS
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
check() {
cd "$_hkgname-$pkgver"
runhaskell Setup test
}
package() {
cd "$_hkgname-$pkgver"
install -D -m744 register.sh "$pkgdir/usr/share/haskell/register/$pkgname.sh"
install -D -m744 unregister.sh "$pkgdir/usr/share/haskell/unregister/$pkgname.sh"
runhaskell Setup copy --destdir="$pkgdir"
install -D -m644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE.md"
}
|