PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=hse
pkgver=3.0.0
pkgrel=4
pkgdesc="Heterogeneous-memory storage engine"
arch=('i686' 'x86_64')
url="https://hse-project.github.io/"
license=('Apache')
depends=('glibc' 'cjson' 'curl' 'libbsd' 'libmicrohttpd' 'liburcu' 'libyaml' 'lz4' 'mongo-c-driver' 'pmdk' 'xxhash')
makedepends=('cmake' 'meson')
options=('staticlibs')
source=("$pkgname-$pkgver-src.tar.gz::https://github.com/hse-project/hse/archive/refs/tags/r$pkgver.tar.gz")
sha256sums=('67e4ac82e004e70ad2dd51d8e4ce4a1611a707e0232b3372e4113921e183328a')


build() {
  cd "$pkgname-r$pkgver"

  meson setup \
    --buildtype=plain \
    --prefix="/usr" \
    -Ddefault_library="both" \
    -Dforce_fallback_for="" \
    "_build"
  meson compile -C "_build"
}

check() {
  cd "$pkgname-r$pkgver"

  #meson test -C "_build"
}

package() {
  cd "$pkgname-r$pkgver"

  meson install -C "_build" --destdir "$pkgdir"
}