blob: f0498c4f9a4a73c5d0ae1270e90d8194979cb95e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Mingi Sung <FiestaLake@protonmail.com>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Radim Hvizdák <hvizdakr at gmail dot com>
pkgname=ibus-hangul-git
_pkgname=ibus-hangul
pkgver=1.5.4+r2+g24bf7fc
pkgrel=1
pkgdesc='Korean input engine for IBus'
arch=('x86_64')
url='https://github.com/libhangul/ibus-hangul'
license=('GPL')
depends=('ibus' 'libhangul' 'iso-codes' 'gtk-update-icon-cache' 'python-gobject')
makedepends=('intltool' 'gnome-common')
provides=(${_pkgname})
conflicts=(${_pkgname})
source=("git+${url}.git")
sha512sums=('SKIP')
pkgver() {
cd ${_pkgname}
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
build() {
cd ${_pkgname}
autoreconf --verbose --force --install
./configure --prefix=/usr --libexecdir=/usr/lib/ibus
make
}
package() {
cd ${_pkgname}
make NO_INDEX=true DESTDIR="${pkgdir}" install
# Fix symlink
ln -sf ../lib/ibus/ibus-setup-hangul "$pkgdir/usr/bin/ibus-setup-hangul"
}
|