blob: 7b6fd1ae68fc7c46f7d2ddee025353c4aaf6e76c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: zotan <aur@zotan.email>
_pkgver=v2024.1-beta4.security2
pkgname=iceshrimp.net-pre-bin
pkgver=2024.1.beta4.security2
pkgrel=1
pkgdesc="Decentralized and federated social networking service, implementing the ActivityPub standard"
arch=(x86_64 aarch64)
url="https://iceshrimp.dev/iceshrimp/iceshrimp.net"
license=(EUPL)
makedepends=()
depends=()
optdepends=(
"ffmpeg: for video transcoding"
)
conflicts=(iceshrimp.net)
provides=(iceshrimp.net)
backup=("etc/iceshrimp.net/configuration.ini")
install="iceshrimp.net.install"
source_x86_64=("${pkgname}-${pkgver}-linux_amd64.tar.zst::https://iceshrimp.dev/iceshrimp/Iceshrimp.NET/releases/download/${_pkgver}/Iceshrimp.NET-${_pkgver}-linux-amd64-glibc.tar.zst")
source_aarch64=("${pkgname}-${pkgver}-linux_arm64.tar.zst::https://iceshrimp.dev/iceshrimp/Iceshrimp.NET/releases/download/${_pkgver}/Iceshrimp.NET-${_pkgver}-linux-arm64-glibc.tar.zst")
source=(
"iceshrimp.net.service"
"iceshrimp.net.sysusers"
"iceshrimp.net.tmpfiles"
"iceshrimp.net.install"
"iceshrimp.net.hook"
)
sha512sums=('cfb7adf7e9f0d9d05ab89b2237ddf1ef4135ed9dde463e96c7cd94e03e497a85c77a795ac20c09214a2364e675c88e65ac119f6de82a08f5c2d64d657c4b3fc0'
'9adf1781842ae7ff2779ca561f06ab2b6fb93e206698084283986627aba69b0fd4482ccbed3daebb2517e5966c326604e1cc57618589f331a966fee2db63815d'
'0665aa7af2b2aa4405289ce9119439ddcc6b9e6c81dc8e3b9ed5d8ecdc4a39d49c950d41d3098ce99fe294ce51a2dee55ec7248c1756783b0e9aad0bde4654fa'
'0a0467df278f3bd739114725b373f5ec6c7296f609f0a9bcb4f8142b44856fc63e32f76390adf757005035dc691a4c54a662cc8a287572b61e215c29e3d3cbf2'
'9c58726b6571268ff4886a6fb8cf6b69db1464d10ef028bae75b93c7fc168abcb6aee3ac9c3c24358805d35e9610ce3102b7270c8ca2e66ec5ad0fbda31f8db9')
sha512sums_x86_64=('620f22880bda0749b32a84160d3d6388bf46444cd6477b4f6ecd157e98d3bdd14fc290978025d62a950f850d67a785cdfcaba0ca927b7ecd8950ce77f05a2324')
sha512sums_aarch64=('feed6c7c219e97062d6417e2e85ef621ef772b10a5f9990f024f47f909d171b1ae9a71d2667eadb7235645c2352d175097c433a62b2d24ad8b5a3f67289b60e3')
pkgver() {
local res
res=${_pkgver//-/.} # Replace dashes with dots
res=${res:1} # Trim leading 'v'
echo -n "$res"
if [[ ${#res} -eq 7 ]]; then
echo -n ".0" # Append .0 to major releases to make sure they sort correctly against prereleases
fi
}
package() {
# Add runtime-only dependencies
depends+=(postgresql libvips openjpeg2)
# Since we're using the release tarballs, we only need the runtime after installation
depends+=('aspnet-runtime>=8.0' 'aspnet-runtime<9.0')
install -dm 755 "${pkgdir}/usr/share/iceshrimp.net"
install -dm 755 "${pkgdir}/etc/iceshrimp.net"
targetarch=${CARCH/x86_64/amd64}
targetarch=${targetarch/aarch64/arm64}
xdir="${srcdir}/Iceshrimp.NET-${_pkgver}-linux-${targetarch}-glibc"
# We are requiring libvips as a system dependency, so we can safely delete this
rm "${xdir}/libvips.so."*
install -Dm 644 "${srcdir}/iceshrimp.net.service" "${pkgdir}/usr/lib/systemd/system/iceshrimp.net.service"
install -Dm 644 "${srcdir}/iceshrimp.net.sysusers" "${pkgdir}/usr/lib/sysusers.d/iceshrimp.net.conf"
install -Dm 644 "${srcdir}/iceshrimp.net.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/iceshrimp.net.conf"
install -Dm 644 "${srcdir}/iceshrimp.net.hook" "${pkgdir}/usr/share/libalpm/hooks/iceshrimp.net.hook"
install -Dm 640 "${xdir}/configuration.ini" "${pkgdir}/etc/iceshrimp.net/configuration.ini"
cp -dpTr --no-preserve=ownership "${xdir}/" "${pkgdir}/usr/share/iceshrimp.net"
}
|