PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Merged with official ABS incidenceeditor PKGBUILD by João, 2021/02/02 (all respective contributors apply herein)
# Maintainer: João Figueiredo & chaotic-aur <islandc0der@chaotic.cx>

pkgname=incidenceeditor-git
pkgver=6.0.40_r1281.g0a6c542
pkgrel=1
pkgdesc="KDE PIM incidence editor"
arch=($CARCH)
url="https://kontact.kde.org"
license=(LGPL-2.0-or-later)
depends=(akonadi-calendar-git akonadi-contacts-git akonadi-mime-git calendarsupport-git eventviews-git gcc-libs glibc kcalendarcore-git kcalutils-git kcodecs-git kcompletion-git kconfig-git kconfigwidgets-git kcontacts-git kcoreaddons-git kdiagram-git ki18n-git kiconthemes-git kidentitymanagement-git kio-git kitemmodels-git kldap-git kmime-git kpimtextedit-git ktextwidgets-git kwidgetsaddons-git kxmlgui-git libakonadi-git libkdepim-git pimcommon-git qt6-base)
makedepends=(git doxygen extra-cmake-modules-git qt6-doc qt6-tools)
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
groups=(kdepim-git)
source=("git+https://github.com/KDE/${pkgname%-git}.git")
sha256sums=('SKIP')

pkgver() {
  cd ${pkgname%-git}
  _ver="$(grep -m1 'set(RELEASE_SERVICE_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"
  _ver=${_ver:-"$(grep -m1 'set(PIM_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"}
  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S ${pkgname%-git} \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}