PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Joermungand <joermungand at gmail dot com>

pkgname=infamousplugins-git
pkgver=0.3.0.r18.gfa6cfeb
pkgrel=1
pkgdesc="A collection of open-source LV2 plugins"
arch=('i686' 'x86_64')
url="http://infamousplugins.sourceforge.net"
license=('GPL2')
groups=('lv2-plugins')
depends=('fftw' 'ntk' 'zita-resampler')
makedepends=('git' 'cmake' 'lv2')
provides=('infamousplugins')
conflicts=('infamousplugins')
source=("${pkgname%-*}"::'git+https://github.com/ssj71/infamousPlugins.git')
md5sums=('SKIP')
options=(!buildflags)

pkgver() {
    cd "$srcdir/${pkgname%-*}"
    git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/${pkgname%-*}"
	mkdir build
	cd build
	cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr ..
	make
}

package() {
    cd "$srcdir/${pkgname%-*}/build"
	make DESTDIR="$pkgdir/" install
	cd ..
    install -Dm644 CHANGELOG "$pkgdir/usr/share/doc/${pkgname%-*}/CHANGELOG"
    install -Dm644 COPYING "$pkgdir/usr/share/doc/${pkgname%-*}/COPYING"
    install -Dm644 README  "$pkgdir/usr/share/doc/${pkgname%-*}/README"
}