PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: zt64 <zt@zt64.dev>
pkgname=jadx-git
pkgdesc='Command line and GUI tools to produce Java source code from Android Dex and APK files'
pkgver='r2190.ce527ed'
pkgrel=3

arch=('any')
url='https://github.com/skylot/jadx'
license=('Apache-2.0')

depends=('java-runtime>=11' 'sh')
makedepends=('git' 'java-environment>=11')
optdepends=()

provides=('jadx')
conflicts=('jadx')

source=("$pkgname::git+$url.git")

sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  cd "$pkgname"
  ./gradlew dist --no-daemon
}

package() {
  cd "${pkgname}/build/jadx"

  install -Dm 755 bin/{jadx,jadx-gui} -t "${pkgdir}/usr/share/java/${pkgname}/bin"
  install -Dm 644 lib/* -t "${pkgdir}/usr/share/java/${pkgname}/lib"

  install -d "${pkgdir}/usr/bin"
  ln -s /usr/share/java/${pkgname}/bin/jadx "${pkgdir}/usr/bin/jadx"
  ln -s /usr/share/java/${pkgname}/bin/jadx-gui "${pkgdir}/usr/bin/jadx-gui"

  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}