blob: 23f48162bc7e7ce7fb2c2242a05f192bad8001b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Co-Maintainer: JakobDev<jakobdev at gmx dot de>
pkgname=jddesktopentryedit
_app_id=page.codeberg.JakobDev.jdDesktopEntryEdit
pkgver=1.6
pkgrel=1
pkgdesc="A graphical program to create and edit desktop entries"
arch=('any')
url="https://codeberg.org/JakobDev/jdDesktopEntryEdit"
license=('GPL-3.0-or-later')
depends=(
'hicolor-icon-theme'
'python-desktop-entry-lib'
'python-pyqt6'
'python-requests'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
'qt6-tools'
)
checkdepends=('appstream')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
noextract=("$pkgname-$pkgver.tar.gz")
sha256sums=('311984a28213ea353bed3cb8bf74c40a5fbbfabcac49b907a2b3fe109e6505f3')
prepare() {
mkdir -p "$pkgname-$pkgver"
bsdtar xf "$pkgname-$pkgver.tar.gz" --strip-components 1 -C "$pkgname-$pkgver"
cd "$pkgname-$pkgver"
# fix typo
sed -i 's/inlcude/include/g' MANIFEST.in
}
build() {
cd "$pkgname-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$pkgname-$pkgver"
appstreamcli validate --no-net "deploy/${_app_id}.metainfo.xml"
desktop-file-validate "deploy/${_app_id}.desktop"
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
python install-unix-datafiles.py --prefix "$pkgdir/usr"
}
|