blob: 0b50ff695f315d53a320523034d6bd8fddc79499 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Maintainer: Michael Lass <bevan@bi-co.net>
# This PKGBUILD heavily borrows from java-openjdk in [extra] maintained by:
# Levente Polyak <anthraxx[at]archlinux[dot]org>
# Guillaume ALAUX <guillaume@archlinux.org>
# This PKGBUILD is maintained on github:
# https://github.com/michaellass/AUR
_majorver=23
_completever=23.0.0
_updatever=37
pkgrel=1
pkgver=${_completever}.u${_updatever}
#_tag_ver=${_completever}+${_updatever}
_tag_ver=${_majorver}+${_updatever}
_versuffix=U
pkgname=jdk-temurin
pkgdesc="Temurin (OpenJDK ${_majorver} Java binaries by Adoptium, formerly AdoptOpenJDK)"
arch=('x86_64')
url='https://adoptium.net/'
license=('custom')
depends=('java-runtime-common>=3' 'java-environment-common' 'ca-certificates-utils' 'desktop-file-utils' 'libxrender' 'libxtst' 'alsa-lib')
optdepends=('gtk2: for the Gtk+ 2 look and feel'
'gtk3: for the Gtk+ 3 look and feel')
provides=("java-runtime-headless=${_majorver}"
"java-runtime-headless-openjdk=${_majorver}"
"java-runtime=${_majorver}"
"java-runtime-openjdk=${_majorver}"
"java-environment=${_majorver}"
"java-environment-openjdk=${_majorver}"
"jdk${_majorver}-openjdk=${pkgver}"
"jdk-openjdk=${pkgver}"
"openjdk${_majorver}-src=${pkgver}"
"openjdk-src=${pkgver}")
replaces=("jdk-adoptopenjdk")
backup=(etc/java-temurin/logging.properties
etc/java-temurin/management/jmxremote.access
etc/java-temurin/management/jmxremote.password.template
etc/java-temurin/management/management.properties
etc/java-temurin/net.properties
etc/java-temurin/sdp/sdp.conf.template
etc/java-temurin/security/java.policy
etc/java-temurin/security/java.security
etc/java-temurin/security/policy/limited/default_local.policy
etc/java-temurin/security/policy/limited/default_US_export.policy
etc/java-temurin/security/policy/limited/exempt_local.policy
etc/java-temurin/security/policy/README.txt
etc/java-temurin/security/policy/unlimited/default_local.policy
etc/java-temurin/security/policy/unlimited/default_US_export.policy
etc/java-temurin/sound.properties)
install=install_jdk-temurin.sh
options=(!strip)
source=(https://github.com/adoptium/temurin${_majorver}-binaries/releases/download/jdk-${_tag_ver/+/%2B}/OpenJDK${_majorver}${_versuffix}-jdk_x64_linux_hotspot_${_tag_ver/+/_}.tar.gz
freedesktop-java.desktop
freedesktop-jconsole.desktop
freedesktop-jshell.desktop)
sha256sums=('630c4f3870056e7e005736ec1edc34ee63a9b45e2027582c52f53a9bf44314b8'
'858f1e7700a3c5658ea2b3874f3ad32b1ffffd1e93c21f7d16b57095c307183d'
'41af2cbeed31a4f463f22fb409de9efe16b38904cdb5b104ae9414d9a7845a03'
'177e31fa4be661c04b6294e6611ee8630dbd303d896ccaa10454511bf72bf63f')
_jvmdir=/usr/lib/jvm/java-${_majorver}-temurin
_jdkdir=jdk-${_tag_ver}
package() {
install -dm 755 "${pkgdir}${_jvmdir}"
cp -a "${srcdir}/${_jdkdir}"/* "${pkgdir}${_jvmdir}"
cd "${pkgdir}${_jvmdir}"
# Conf
install -dm 755 "${pkgdir}/etc"
mv conf "${pkgdir}/etc/java-temurin"
ln -sf /etc/java-temurin conf
# Legal
install -dm 755 "${pkgdir}/usr/share/licenses"
mv legal "${pkgdir}/usr/share/licenses/${pkgname}"
ln -sf /usr/share/licenses/${pkgname} legal
# Man pages
for f in man/man1/*; do
install -Dm 644 "${f}" "${pkgdir}/usr/share/${f/\.1/-temurin${_majorver}.1}"
done
rm -rf man
ln -sf /usr/share/man man
# Link JKS keystore from ca-certificates-utils
rm -f lib/security/cacerts
ln -sf /etc/ssl/certs/java/cacerts lib/security/cacerts
# Desktop files
for f in jconsole java jshell; do
install -Dm 644 \
"${srcdir}/freedesktop-${f}.desktop" \
"${pkgdir}/usr/share/applications/${f}-${pkgname}.desktop"
done
}
|