blob: cc200ca7c6ee04d7b6de0c8baee58d5937b40d94 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Michael Thies <mail@mhthies.de>
pkgname=justbuild
pkgver='1.4.1'
pkgrel=1
pkgdesc="A generic build system supporting multi-repository builds"
arch=('x86_64')
url="https://github.com/just-buildsystem/justbuild"
license=('Apache-2.0')
depends=('glibc' 'gcc-libs' 'fmt' 'openssl' 'zlib' 're2' 'c-ares' 'grpc' 'abseil-cpp' 'curl' 'python' 'protobuf' 'libarchive' 'libgit2')
makedepends=('clang' 'binutils' 'wget' 'cli11' 'microsoft-gsl' 'nlohmann-json' 'pandoc')
conflicts=('just' 'just-git' 'just-js')
source=("justbuild-${pkgver}.tar.gz::https://github.com/just-buildsystem/justbuild/archive/v${pkgver}.tar.gz"
"gsl.pc")
sha256sums=('a8261fe2256d84eedd7b5e19ef3e8d70a249b160f6d86dc4e06f9818c4a7b721'
'c08f3e53356b1b258bb195ae0c2437f53269d7751d94800a46f75a3465346afe')
build() {
cd "${srcdir}/justbuild-${pkgver}"
# Clean build directory from potential previous run
# The bootstrap script expects the build directory to be clean; esp. src, dep_includes and deps must not be present
[[ -d "${srcdir}/build/src" ]] && rm -rf "${srcdir}/build"
mkdir -p "${srcdir}/build"
# Bootstrap just
env JUST_BUILD_CONF='{"COMPILER_FAMILY": "clang", "CC": "/usr/bin/clang", "CXX": "/usr/bin/clang++", "AR": "/usr/bin/ar", "FINAL_LDFLAGS": ["-Wl,-z,relro,-z,now"]}'\
PKG_CONFIG_PATH="${srcdir}"\
PACKAGE=YES\
LOCALBASE=/usr\
NON_LOCAL_DEPS='["bazel_remote_apis", "google_apis"]'\
python3 ./bin/bootstrap.py . ${srcdir}/build
# Build compiled just-mr
../build/out/bin/just install 'installed just-mr' -c ../build/build-conf.json -C ../build/repo-conf.json --output-dir ../build/out
# convert man pages from Markdown to man
find "${srcdir}/justbuild-${pkgver}/share/man" -name "*.md" -exec sh -c 'pandoc --standalone --to man -o "${0%.md}.man" "${0}"' {} \;
}
package() {
install -m 755 -Dt "${pkgdir}/usr/bin" "${srcdir}/build/out/bin/just"
install -m 755 -Dt "${pkgdir}/usr/bin" "${srcdir}/build/out/bin/just-mr"
install -m 755 -DT "${srcdir}/justbuild-${pkgver}/bin/just-import-git.py" "${pkgdir}/usr/bin/just-import-git"
install -m 755 -DT "${srcdir}/justbuild-${pkgver}/bin/just-deduplicate-repos.py" "${pkgdir}/usr/bin/just-deduplicate-repos"
# bash completion
mkdir -p "${pkgdir}"/usr/share/bash-completion/completions
install -m 0644 "${srcdir}/justbuild-${pkgver}"/share/just_complete.bash "${pkgdir}"/usr/share/bash-completion/completions/just
# man
mkdir -p "${pkgdir}"/usr/share/man/{man1,man5}
install -m 0644 -t "${pkgdir}"/usr/share/man/man1 "${srcdir}/justbuild-${pkgver}"/share/man/*.1.man
install -m 0644 -t "${pkgdir}"/usr/share/man/man5 "${srcdir}/justbuild-${pkgver}"/share/man/*.5.man
find "${pkgdir}"/usr/share/man -name "*.man" -exec sh -c 'mv "$1" "${1%.man}"' _ {} \;
}
|